~c1 742
~V1	KEY INPUT
~V2	MAIN CASE
~V3 	fill Count
~V4 	RETURN START STATUS
~V5 	current adjusted feed (feed-preact)
~V6	scratch
~V7     EDIT DECIMAL
~V8     CURRENT INGREDIENT 
~V9	return password status
~V10	CUT 1
~V11	PRE 1
~V12	CUT 2
~V13	PRE 2
~V14	CUT 3
~V15	PRE 3
~V16	TARE zero range tolerance
~V17    TARE delay
~V18    GROSS ZERO TOLERANCE
~V19	MIXER TIMER
~V20	MIXER TIME OUT
~V21    DOWN LOAD COMPLETE
~V22	delay after cut off   
~V23	REMOTE LOCAL
~V24	MOTION TOL
~V25-V28INGREDIENT NET WEIGHT MEMORY
~V30	current cut off 
~V31	CURRENT OUTPUT
~V32    hand add tare = 1
~V33    mixer time out started
~V34   master/slave 1=master
~V35   master/slave return status for d22
~V65	scrap
~V66	scrap
~
~OUT 1  ingred. 1
~OUT 2  ingred. 2
~OUT 4 ingred. 3
~OUT 8 MIXER
~OUT 10 CONTROLLER 2 DONE/START
~OUT 20 spare
~OUT 40 SPARE
~OUT 80 spare
~
~IN  1  START
~IN  2  STOP
~IN  3  ACCEPT
~IN  4  MIXER VALID
~IN  5  CONTROLLER 2 COMPLETE/START2
~IN 6   AUTO
~
~
D10.
m=V24
iV7 > 3
{
V7=0
}
V2=0			~init case
f1=0			~background cut offs disabled
f2=0
L5			~lock enter key
D11.
OXXX0XXXX		~REMOVE CONTROLLER 2 START
f1=0
f2=0
U1
U2
U4
P1@"(READY)  (COUNT "V3.0.5")"@
V1=K			~read keypad to variable 1
CV1			~go to case assigned by variable 1 
[
c256.			~no key
b
c0.	
x2.					
b	
c6.
x19.
iV9=1
 {
 U7			      	~unlock keypad
 }
b
c8.
x18.				~clear count
b
c9.
x19.
iV9=1
{
x9.
}
b
]
iI2=1			~stop off
{
 O00000000		~all off but ...  			
 x13.
 iV4=1			~if start... see d13
  {
   V8=0			~FIRST INGREDIENT
   V2=0
   L7
   V33=0		~MIXER TIME OUT NOT STARTED
   P2@"  "@
   G15.			~start the fill
  }     
}
e
{
 O00000000			~insure all off-  STOPPED
} 
G11.
D15.
iI2=0
{
 V1=256
 G11.				~CHECK FOR STOP
}
iI6=1
{
 V1=256
 G11.				~CHECK FOR manual
}
iV33=1
{				~mixer time out started
 iw4=0
 {
  OXXXX0XXX			~if timed out off mixer
  V33=0
 }
}
CV2
[
c0.
P1@"STARTING"@
x1.
b
c1.
x22.
iV35=1				~controller 1 remote ?
{
  P1@"SETUP REQUEST"@
  V21=0
  P3@"\2V\r\3"@
  d20 
  w1=100
  x1.
}
e
{
 V2=3
}
b
c2.
iV21=7
{
 x1.
}
iw1=0				~no answer time out retry
{
 V2=1
}
b
c3.
V6=W1
iV6<0
{
 (V6=V6*-1)
}
iV6<V18
{
 x1.
}
e
{
 P1@"GROSS ZERO ERROR"@
 d20
 G11.
}
b
c4.
(V6=V8*2)			~GET THE CURRENT CUT OFF ... SAVE IN V30
(V6=V6+10)
V30=VV6
(V6++)
(V30=V30-VV6)
V6=V8
V31=1
D98.
iV6=0
{
}
e
{
(V31=V31*2)			~V31 WILL BE THE OUTPUT
(V6=V6-1)
G98.
}
x1.
b
c5.				~RETRY TARE HERE
V32=0
P1@"TARING"@
M=0
x5.				~tare scale
x1.
b
c6.
P1@"WAITING"@
x6.				~wait for tare
w3=V17				~zero stable delay
b
c7.
x7.				~check for net 0.. if not tare again
b
c8.	
P1@"RUNNING"@
F1.0^V30OV31A0			~background on fast feed		
x1.
b
c9.
if1=0
{
 (V8++)
 x1.
}	
b
c10.
P1@"AFTER CUT DELAY"@
w1=V22				~start after cut off delay
x1.
b
c11.
iw1=0
{
 x1.
}
b
c12.
x20.
d20
(V6=S&2)
iV6=2
{
 (V6=V8+24)			~ADD ONLY 24 NOT 25  V8 HAS BEEN INCREMENTED
 VV6=W0
 P4@W0.8"\r\n"@
 x1.
}
b
c13.
iV8<3
{
V2=4
}
e
{
 x1.
}
b
c14.
x1.
b
c15.				~SECOND RETRY TARE HERE
V32=1
P1@"TARING"@
M=0
x5.				~tare scale
x1.
b
c16.
P1@"WAITING"@
x6.				~wait for tare
w3=V17				~zero stable delay
b
c17.
x7.				~check for net 0.. if not tare again
b
c18.
P1@"HAND ADD (PRESS ACCEPT)"@
iI3=0
{
 iV34=1				~controller 1  remote ?
 {
  OXXX1XXXX			~START CONTROLLER 2
 }
 x1.
}
b
c19.
x20.
d20
(V6=S&2)
iV6=2
{
 V28=W0
 P4@W0.8"\r\n"@
 x1.
}
b
c20.
x1.
b
c21.
OXXXX1XXX		       ~ON MIXER
w2=V20
x1.
b
c22.
iI4=0
{
 w4=V19
 V33=1				~mark mixer time out started
 x1.				~mixer ok
}
iw2=0
{
 P1@"MIXER FAILURE (START TO RETRY)"@
 iI1=0
 {
  V2=21
  P1@"MIXER RETRY"@
 }
}
b
c23.
iV33=0
{
 x1.		
}
e
{
 P1@"MIXER TIMING"@
}
b
c24.
iV34=1				~controller 1 ?
{
  iV23=1				~remote ?
 {
    iI5=0				~batch complete from remote
   {
     OXXX0XXXX			~REMOVE CONTROLLER 2 START
     x21.
    w1=100
     x1.
   }
  e
  {
     P1@"WAITING FOR CONTROLLER 2"@
  }
 }
 e
  {
    x1.
  }
}
e
{
  P1@"CONTROLLER 2 DONE"@
  OXXX1XXXX			~SEND CONTROLLER 2 DONE
  d30
  x1.
}
b
c25.
iV34=1				~controller 1 ?
{
  iV23=1				~remote ?
 {
   iV21=7				~batch data uploaded
  {
   x1.
  }
  iw1=0
  {
    x21.
    w1=100				~time out resend batch complete
  }
 }
 e
 {
   x1.
 }
}
e
{
 OXXX0XXXX				~controller 2 off done
 x1.
}
b
c26.
P4@V25.V7.8"\r\n"V26.V7.8"\r\n"V27.V7.8"\r\n"V28.V7.8"\r\n"@
OXXX0XXXX			~REMOVE CONTROLLER 2 START/DONE
(V3++)				~increment bag count
G11.				~ALL DONE
V1=256
b
]
G15.
E
~
~	Begin subroutines
D1.
(V2++)					~increment state counter
E
D2.
V66=1
V6=10					~IST CUT OFF
x3.
D99.
P1@"ENTER INGREDIENT CUT OFF "V66.V7.1@VV6=kV7.8	~get feed cut off
(V6++)
x14.
P1@"ENTER PREACT "V66.V7.1@VV6=kV7.8			~get preact
x14.
(V6++)
(V66++)
iV66<4
{
 G99.
}
x4.
E
D3.
P0@" "@					~blank big display
P1@" "@					~blank disp 1
E
D4.
P1@" "@					~blank all text
P0@"\0"@P1@" "@				~release big display 
E
D5.TE
D6.
(V6=S&512)			~tare in process to variable 7
iV6=512{}			~if tare in process (do nothing)
e{x1.}
E	
D7.				~tare within zero tolerances ?
iw3=0
{				~stable delay satisfied?
  V6=W0
  iV6 < 0
  {
   (V6=V6 * -1)			~abs wt for range compare
  }				
  iV16<V6
  {
   iV32=0
   {
    V2=5
   }
   e
   {
    V2=15
   }
  }
  e
  {
   x1.
  }
}
e
{
}
E
D9.
x3.
P1@"EDIT DECIMAL"@V7=k0.1	 		~EDIT DECIMAL
x14.
P1@"TARE TOLERANCE"@V16=kV7.8		 	~get tare zero tol.
x14.
P1@"ENTER TARE DELAY (.1 secs)"@V17=k0.3 	~get zero stable delay
x14.
P1@"GROSS ZERO TOLERANCE"@V18=kV7.8		 ~get  zero tol.
x14.
(V19=V19/10)
P1@"MIXER TIMER (secs)"@V19=k0.5		~GET MIXER TIMER DELAY
(V19=V19*10)
x14.
P1@"MIXER TIMEOUT (.1 secs)"@V20=k0.3		~GET MIXER TIME OUT DELAY
x14.
P1@"AFTER CUT OFF DELAY (.1 secs)"@V22=k0.3	~GET AFTER CUT OFF DELAY
x14.
P1@"MOTION TOLERANCE (1=0.25d)"@V24=k0.2	~motion tolerance
x14.
P1@"LOCAL=0 REMOTE=1"@V23=k0.1		~AUTO MODE
x14.
P1@"CONTROLLER1=1 CONTROLLER2= 2"@V34=k0.1			~AUTO MODE
x4.
E
D13.
V4=0					~put desired start conditions after this 
iI6=0
{ 
 iV34=1					~controller 1 ?
 {
   iI1=0
  {
   V4=1
  }
 }
 e
 {
  iI5=0
  {
   OXXX0XXXX
   V4=1
  }
 }
}
E
D14.
P1@" "@
E
D18.
x3.
P1@"ENTER STARTING COUNT"@V3=k0.5	~STARTING BAG COUNT
x4.
E
D19.
 x3.
 V9=0
 P1@"ENTER PASSWORD"@
 V1=0
 V1=k0.5
 x4.
 iV1=2001
 {
 V9=1			      	~password good
 }
E
D20.
P1@"WAITING FOR STABLE WEIGHT"@
E
D21.
P1@"SEND BATCH COMPLETE"@
V21=0
P3@"\2B\r\3"@
d20
E
D22.
V35=0
iV34=1				~controller 1 ?
{
  iV23=1				~remote ?
 {
  V35=1
 }
}
E
~
~
E				~end program