~SLAVE FLIPFLOP controller
~V1	KEY INPUT
~V2	MAIN CASE
~V3 	final feed cuttoff
~V4 	fast feed cut off
~V5 	current adjusted feed (feed-preact)
~V6	current preact 
~V7     current fast cut off (feed - fast feed)
~V8     SCRATCH
~V9	zero range tolerance
~V10    zero tol. delay
~V11    auto tare enable
~V12    auto print enable
~V13    spare
~V14    MIN ZERO TOL
~V15    discharge delay
~V16	cut off type 0=cascade 1=sequencial
~V17    MAX ZERO TOL
~V18    return password/START status
~V19	delay after cut off
~V20	RETURN START STATUS
~V22	EDIT DECIMAL
~V23    discharge enable
~V50	Preact ready
~V51    Preact size
~V52    Preact adjust
~V53    Preact pointer
~V54-V64 Preact queue
~V65	scrap
~V66	scrap
~V67    accumulator ENABLE
~V68    ACCUMULATOR
~V69    MOTION TOLERANCE
~V70    ready for resume
~V71    WHO'S RUNNING
~V73    READY STATUS
~V72    STOPPED SENT
~OUT 5  FAST FEED
~OUT 6  FINAL FEED
~OUT 7	DISCHARGE
~OUT 8	spare
~OUT 10 SPARE
~OUT 20 spare
~OUT 40 SPARE
~OUT 80 spare
~
~IN  1  START
~IN  2  STOP
~IN  3  spare
~
~
D10.
V70=0
V72=0
m=V69
iV22 > 3
{
V22=0
}
V16=0
V2=0			~init case
V1=0			~init key input
f1=0			~background cut offs disabled
f2=0
iV53>63
{
V53=54			~init preact pointer if out of range
}
L5			~lock enter key
D11.
OXXX0XXXX		~NOT FILLING
iW1>V14			~is there a box
  {
   iW1<V17
   {
    OXX0XXXXX		~READY
    V73=1
   }
   e
   {
    OXX1XXXXX     
    V73=2     
   }
  }
e
{
 OXX1XXXXX              ~NO BOX
 V73=3
}
f1=0
f2=0
U1
U2
U4
iV70=0
{
 CV73
 [
   c1.
   P1@"READY"@
   b
   c2.
   P1@"REMOVE BOX"@
   b
   c3. 
    P1@"ADD BOX"@
   b
 ]
}
e
{
 P1@"PAUSED"@
}
V1=K			~read keypad to variable 1
CV1			~go to case assigned by variable 1 
[
c256.
b
c0.	
x2.					
b	
c4.
V70=0
b
c6.
x19.
iV18=1
 {
 U7			      	~unlock keypad
 }
b
c9.
 x19.
 iV18=1
 {
 x9.
 }
b
]
iI2=1			~stop off
{
  V72=0
  iI1=0			~if start input 0 & stop=1 start 
   { 
     L7
     iV70=0
     {			~start
      x13.
      iV18=1
       {
        V2=0
        G15.		~start the sequence
       }
     }
     e
     {			~resume
       x21.
       G15.
     }
     
   }  
}
e
{
 O00000000			~insure all off- 
 iI1=0
  {
    V70=0			~start with stop is resume
  }
} 
G11.
D15.
iI2=0
{
 V70=1				~SET RESUME
 O00000000			~send stop to slave
 G11.				~CHECK FOR STOP
}
CV2
[
c0.
  P1@"STARTING"@
  x1.
b
c1.
 (V2++)
b
c2.
 (V2++)
b
c3.
iV11=1
{
 iW1<V17
 {
  P1@"TARING"@
  M=0
  T				~tare scale
 }
 e
 {
  P1@"CLEAR SCALE"@
  V2=0
 }
}
e
{
 (V2=V2+2)			~cause inc. past tare states
}
x1.
b
c4.
x6.				~wait for tare
w3=V10				~zero stable delay
b
c5.
x7.				~check for net 0.. if not tare again
b
c6.	
P1@"RUNNING"@		
F2.0^V5O64A0			~background on  feed
x1.
b
c7.
if2=0
 {
  x1.
 }
b
c8.
V2=0				~ALL DONE loop in run case
V70=0
G11.
b
]
G15.
E
~
~	Begin subroutines
D1.
(V2++)					~increment state counter
E
D2.
x3.
P1@"ENTER SLOW FEED CUT OFF"@V3=kV22.8	~get feed cut off
x14.
P1@"ENTER FAST FEED CUT OFF"@V4=kV22.8	~get feed cut off
x14.
P1@"ENTER PREACT"@V6=kV22.8		~get preact
x14.
(V5=V3-V6)			~calculate adjusted feed cut off
(V7=V5-V4)			~calculate adjusted fast feed cut off
x4.
V50=0					~INIT PREACT
V53=54
E
D3.
P0@" "@					~blank big display
P1@" "@					~blank disp 1
E
D4.
P1@" "@					~blank all text
P0@"\0"@P1@" "@				~release big display 
E
D6.
(V8=S&512)			~tare in process to variable 7
iV8=512{}			~if tare in process (do nothing)
e{x1.}
E	
D7.				~tare within zero tolerances ?
iw3=0
{				~stable delay satisfied?
  V8=W0
  iV8 < 0
  {
   (V8=V8 * -1)			~abs wt for range compare
  }				
  iV9<V8
  {
   V2=0
  }
  e
  {
   x1.
  }
}
e
{
}
E
D9.
x3.
P1@"EDIT DECIMAL"@V22=k0.1	 	~EDIT DECIMAL
x14.
P1@"1=ENABLE AUTO TARE"@V11=k0.1	 ~TARE ENABLE
x14.
P1@"TARE TOLERANCE"@V9=kV22.8		 ~get tare zero tol.
x14.
P1@"ENTER TARE DELAY (.1 secs)"@V10=k0.3 ~get zero stable delay
x14.
P1@"ENTER MAX ZERO TOL."@V17=kV22.8		~
x14.
P1@"ENTER MIN ZERO TOL."@V14=kV22.8		~
x14.
P1@"ENTER MOTION TOLERANCE"@V69=k0.3	
m=V69
x4.
E
D14.
P1@" "@
E
D19.
 x3.
 V18=0
 P1@"ENTER PASSWORD"@
 V1=0
 V1=k0.5
 x4.
 iV1=2001
 {
 V18=1			      	~password good
 }
E
D21.
 CV2
 [
  c4.
   V2=3
  b
  c5.
   V2=3
  b
  c7.
   V2=6
  b
 ]
 P1@"RESUMING"@
 OXX11XXXX		 ~NOT READY/NOT COMPLETE
 d30	
E
D13.
 V18=0
 iW1<V17		~try to start A first... is the box not full
 {
  iW1>V14		~is there a box
  {
   V18=1
   V71=1			~MARK A RUNNING
   P1@"STARTING"@
   OXX11XXXX		 ~NOT READY/NOT COMPLETE
  }
  e
  {
   P1@"ADD BOX"@
   OXX1XXXXX		~NOT READY
  }
 }
E
~
~
E				~end program