~V1 SCRATCH
~V2 SCRATCH
~V3 AVG SAMPLE WT
~V5 PIECE WT
~V7 SAMPLE SIZE
~V11 SCRATCH
~V12 SCRATCH
~V17 MODE 0=NORM 1=COUNT
~V18 SCALE SELECT
~V22 DECIMAL1
~V23 DECIMAL 2
~V24 SAMPLE AVG SIZE
~V25 sample motion scale 1
~V26 normal motion scale 1
~V27 sample motion scale 2
~V28 normal motion scale 2
~V29 count
~V30 0=single scale 1=dual scale
~V31 motion time out
~V32 scale 1 countby
~V33 scale 2 countby
~V34 target count
~V35 mode 0=add to count 1=zeroing 2=zero
~V36 tote weight
~V37 response var
~V38 temp count
D10.
L5
V18=1
sV18
m1=V26
m2=V28
V17=0
iV30>0
{
 P2@"SCALE "V18.0.1@
}
D11.
iV17=0
{
 iV5>0
 {
  P1@"READY "@
 }
 e
 {
  P1@"SAMPLE"@ 
 }
}
e
{
 iV5>0				~pw greater than 0
 {  				~V35 mode 0=add to count 1=zeroing 2=zero
  CV35
  [
   c0.
    (V11=SV18&2)
    iV11=0
    { 
     P2@"STANDBY"@
    }
    e
    {
     (V11=WV18.0/V5)
     (V38=V29+V11)     	
     x15.
     (V11=V34-0.49)
     iV38<V11
      {
       V29=V38
       V35=1           ~below desired count
       P2@" "@
      }
     e
      {
       (V11=V34+0.51)
       iV38<V11
       {
        V29=V38
        V35=3		~COUNT CORRECT
       }
       e
       {
        P2@"COUNT HIGH REMOVE PIECES"@
       }
      }
    }
   b
   c1.
    TV18		~zero
    MV18=1		~MODE TO GROSS
    P2@"TARING"@
    d20
    (V11=SV18&512)
    iV11=512
    {
    }
    e
    {
     V35=2
    }
   b
   c2.
    P2@"READY"@
    (V11=WV18.0/V5)
    iV11<0.51
    {
     iV11<-0.51
     {
      V35=0             ~TOOK PIECES OFF
     }
    }
    e
    {
     V35=0		~PUT PIECES ON
    }
   b
   c3.
    P2@"COUNT COMPLETE REMOVE TOTE"@    
    iWV18.1<V36				~WAIT FOR LESS THAN zero return tol
    {
     V35=4
     V29=0
     V38=0
     P0@V29.0.10@
    }
   b
   c4.
    P2@"LOAD EMPTY TOTE"@
    V11=WV18.1
    iV11<0
    {
     (V11=V11 * -1) 			~abs wt
     iV11<V36
      {
       V35=5
      }
    }
    e
    {    
      V35=5
    }
   b
   c5.
    x3.
    V37=0
    P1@"CONTINUE=0 RESAMPLE=1"@V37=k0.1
    x4.
    iV37=0
    {
     P1@"^^^^^^^^^^^^COUNT^^^^^^^^^^^^^"@
     V35=6
    }
    e
    {
      x12.
    }
   b
   c6.
     ZV18
     tV18=0
     MV18=1		~MODE TO GROSS
     P2@"ZEROING"@
     (V11=SV18&256)
     iV11=256
     {
     }
     e
     {
      P0@V38.0.10@
      V35=2
     }
   b
  ]
  P0@V38.0.10@
 }
 e
 {
  P1@"TAKE SAMPLE"@
  d20
  x16.
 }
}
V2=K
CV2
[
c256.
b
c1.
V18=1
x12.	~sample scale 1
b
c2.
V18=2
x12.
b
c3.
x15.	~count mode
b
c4.
x16.    ~weight mode
x17.
b
c5.
iV18=1	~switch scale
{
 iV30=1
 {
  V18=2
 }
}
e
{
 V18=1
}
sV18
x17.
b
c6.
x20.
b
c9.
x19.
iV1=1
{
 x9.
}
b
c0.
x19.
iV1=1
{
 U5
}
b
]
G11.
D12.
x3.
mV18=V25	~apply sample motion
d2		~insure new tol. is in affect
ZV18		~zero
tV18=0
MV18=1		~MODE TO GROSS
P1@"ZEROING"@
w1=V31
D122.
(V11=SV18&256)
iV11=256
{
 iw1=0
 {
  P1@"TARE ERROR"@
  d20
  V5=0
  V3=0
  G124.
 }
 e
 {
  G122.
 }
}
P1@"PLACE SAMPLE & ENTER SIZE"@V7=k.0.3
x14.
D125.					~RESTART SAMPLE POINT
P1@"STANDBY"@
w1=V31
D123.
(V11=SV18&2)
iV11=0
{
 iw1=0
 {
  P1@"MOTION ERROR"@
  d20
  V5=0
  V3=0
  G124.
 }
 e
 {
  G123.
 }
}
iV18=1
{
 V12=V32
}
e
{
 V12=V33
}
iWV18.4<V12
{
  P1@"SAMPLE TOO SMALL"@
  d20
  V5=0
  V3=0
  G124.
}
P1@"CALCULATING"@
V1=0
V2=0
(V12=V24-1)
D121.
(V2=WV18.4+V2)
d1
(V1++)
iV1>V12
{
}
e
{
(V11=SV18&2)
iV11=0
 {
  G125.		~MOTION ERROR RESTART SAMPLE
 }
 e
 {
  G121.
 }
}
(V3=V2/V24)
(V5=V3/V7)
V29=0
V38=0
V35=0
V17=1				~switch to count mode
D124.				~error exit point
x4.
x17.
iV17=0
{
 x21.
}
m1=V26				~restore normal motion
E
D3.
P0@" "@					~blank big display
P1@" "@					~blank disp 1
P2@" "@
E
D4.
P1@" "@					~blank all text
P0@"\0"@  				~release big display 
E
D14.
P1@" "@
E
D15.
x3.
V17=1
P1@"^^^^^^^^^^^^COUNT^^^^^^^^^^^^^"@
x17.
E
D16.
x4.
V17=0
E
D17.
iV30=1
{
 P2@"SCALE "V18.0.1@
}
e
{
 P2@" "@
}
E
D19.
 x3.
 V1=0
 P1@"ENTER PASSWORD"@
 V11=0
 V11=k0.5
 x4.
 iV11=2001
 {
 V1=1			      	~password good
 }
x17.
x21.
E
D9.
x3.
P1@"SCALE 1 DECIMAL"@V22=k0.1	 	~SCALE 1 DECIMAL
x14.
P1@"SCALE 2 DECIMAL"@V23=k0.1	 	~SCALE 2 DECIMAL
x14.
P1@"SCALE 1 MIN. SAMPLE"@V32=kV22.2
x14.
P1@"SCALE 2 MIN. SAMPLE"@V33=kV23.2
x14.
P1@"SAMPLE AVG. SIZE"@V24=k0.2	        ~
x14.
P1@"SAMPLE MOTION TOLERANCE 1"@V25=k0.3	
x14.
P1@"NORMAL MOTION TOLERANCE 1"@V26=k0.3
x14.
P1@"SAMPLE MOTION TOLERANCE 2"@V27=k0.3	
x14.
P1@"NORMAL MOTION TOLERANCE 2"@V28=k0.3
x14.
P1@"SINGLE SCALE=0 DUAL=1"@V30=k0.1
x14.
P1@"MOTION TIME OUT"@V31=k0.3
x14.
P1@"TARGET COUNT"@V34=k0.3
x14.
P1@"ZERO TOLERANCE"@V36=k.0.5
m1=V26
m2=V28
x4.
x21.
x17.
E
D20.
x3.
P1@"ENTER PIECE WT"@V5=k4.5
x4.
x17.
x21.
E
D21.
iV17=1
{
 x15.
}
e
{
 x16.
}
E