~use 869xx
~V1	KEY INPUT
~V2	MAIN CASE
~V3     scrap
~V4     SCRAP
~V5     current low
~V6     Current high
~V18    computer on line
~V19    barcode message waiting
~V20    transaction ready
~V21    COMPUTER TIME OUT
~V22	EDIT DECIMAL
~V23    desired wt queue
~V24    check weigh weight
~V25    checkweigh status 0=out 1=ok
~V26    IN TOL OUT OF TOL PULSE TIME
~V50-V59 stored weights
~V60     weight pointer
~V70-V81 TOLERANCE MEM. 70=LOW 71=HIGH FOR SET 1, 72=LOW 73=HIGH FOR SET 2 ...
~V99    password stat.
~A1-A6  id strings
~A7     current id
~A20    id input from keyboard or computer

D10.
V19=0			~clear bar waiting flag
V20=0			~CLEAR TRANS. READY
t=0			~CLEAR TARE
M=1			~GROSS MODE
L5			~LOCK PRINT
L3			~lock enter key
x21.			~READY MESSAGE
V60=50
D11.
VV60=W1
(V60++)
iV60>59
{
 V60=50
}
V1=K			~read keypad 
CV1			~go to KEY CASE
[
c256.
b
c1.
x17.
x21.
b
c2.			~setup check tols.
x20.
x21.
b
c6.
x19.
iV99=1
 {
 U7			      	~unlock keypad
 }
x21.
b
c9.
x19.
iV99=1
{
x9.
}
x21.
b
] 
iV19=1		~barcode scanned
{
 x16.		~get id and tolerances
x22.
 V2=0
 V19=0		~clear barcode ready flag
 (V4=V60-V23)   ~get history wt
 iV4>49
 {
 }
 e		
 {
  (V4=V4+10)
 }
 V24=VV4
 G15.		~go checkweigh
}
G11.
D15.
CV2
[
c0.
 V25=1		~start with in tol.
 iV24<V5
 {
  V25=0		~under
 }
 iV24>V6
 {
  V25=0		~over
 }
 (V2++)
b
c1.
 iV25=1
 {
  OXXXXXX01	~SEND IN TOL
 }
 e
 {
  OXXXXXX10	~SEND OUT OF TOL
 }
 w1=V26		~start output pulse time
 (V2++)
b
c2.

 iV18=1
 {
  V20=1
  P8@A7","V24.V22.6","V25.0.1",\26"@
  w2=V21	~start com timer
  (V2++)
 }
 e
 {
  (V2=V2+2)
 }
b
c3.
 iw1=0
 {
  OXXXXXX00
 }
 iV20=1
 {
  iw2=0		~COM TIMED OUT
  {
   (V2++)
  }
 }
 e
 {
   (V2++)
 }
b
c4.
 iw1=0
 {
  OXXXXXX00	~OFF STATUS
  G11.
 }
b
]
G15.
E
~
~	Begin subroutines
D1.
(V2++)					~increment state counter
E
D3.
P0@" "@					~blank big display
P1@" "@					~blank disp 1
E
D4.
P1@" "@					~blank all text
P0@"\0"@P1@" "@				~release big display 
E
D9.
x3.
P1@"EDIT DECIMAL"@V22=k0.1	 	~EDIT DECIMAL
x14.
P1@"ENABLE COMPUTER 1=YES"@V18=k0.1
x14.
P1@"COMPUTER TIME OUT"@V21=k0.4
x14.
P1@"HISTORY WEIGHT"@V23=k0.1
x14.
P1@"OUTPUT TIME"@V26=k0.5
x4.
E
D14.
P1@" "@
E
D19.
 x3.
 P2@" "@
 V99=0
 P1@"ENTER PASSWORD"@
 V1=0
 V1=k0.5
 x4.
 iV1=2001
 {
 V99=1			      	~password good
 }
E
D16.
V3=s1.6.20
iV3>0				~GOOD ID GET TOL. VALUES AND SAVE ID TO A7
{
 (V4=V3-1)
 (V4=V4*2)
 (V4=V4+70)
 V5=VV4
 (V4++)
 V6=VV4
 P7A7@A20@
}
e
{
 V5=0				~BAD ID NUMBER 
 V6=0
 P7A7@"999999999999999"@ 
}
E
D17.
x3.
P1@"ENTER SETUP ID"@
A20.17
P2@" "@
x16.
x4.
E
D20.
x3.
P2@" "@
V3=0
P1@"ENTER SETUP(1-6) (EXIT=0)"@V3=k0.1	 	
x14.
iV3>0			~insure 1-6
{
 iV3<7
 {  
  (V4=V3-1)
  (V4=V4*2)
  (V4=V4+70)		~INDEX TO TOLERANCE ARRAY
  P1@"ENTER ID NUMBER"@
  AV3.17
  P2@" "@
  P1@"ENTER LOW TOLERANCE"@VV4=kV22.6
  x14.
  (V4++)
  P1@"ENTER HIGH TOLERANCE"@VV4=kV22.6
  x14.
  G20.
 }
}
P2@" "@
x4.
E
D21.
 P1@"READY"@
 P2@A7V5.V22.6V6.V22.6@
E
D22.
 P2@A7V5.V22.6V6.V22.6@
E
~
~
E				~end program