~AXLE SCALE USE PROGRAM 742XX
~V87 key read
~V70 current axle
~V88 INCREASE WEIGHT
~V89 INCREASE TIME
~V90 DECIMAL LOCATION
~V91 ZERO TOLERANCE
~V92 OFF ZERO FLAG
~V93 MIN. AXLE WEIGHT
~V94 STATE VARIABLE
~V95 total time out
~V96 HISTORY WT.
~OUTPUTS
~GREEN 5
~RED   6

D6.
 V15=0
 P3@"       \r"@
E
D7.
 (V9=S&4)
 iV9=0
 { 
   P3@W1.7"\r"@ 
 }
 e
 {
  P3@"-------\r"@
 }
 w3=3
E


D10.
V15=1
V94=0
V70=1
L3
L2
L4
L5
D11.

iw3=0
{
 iV15=1
  {
   x7.
  }
}

M=1
V87=K
CV87
[
c256.					~NO KEY
b
c6.
V15=0
x6.
x96.
iV100=1
{
 U7
}
V15=1
b
c8.
V15=0
x6.
x60.
V15=1
b
c9.
x6.
V15=0
x96.
iV100=1
{
 x40.					~setup
}
V15=1
b
]
CV94
[
c0.					~leave zero/green light
iW1<V93					~WEIGHT > MAX. AXLE
{
 OXX01XXXX
 P1@"WAITING FOR AXLE "V70.0.1@
}
e
{
 V96=W1					~HISTORY WT
 x95.
 w1=V89					~init increase timer
}
b
c1.		
P1@"WAITING FOR AXLE "V70.0.1@			~weight increase/stop light
(V100=W1-V96)				~WEIGHT INCREASE
iV100<0
 {
  (V100=V100 * -1)
 }
iV100<V88
{
 iw1=0
 {
  OXX10XXXX				~STOP
  x95.
 }
}
e
{
 w1=V89					~restart time
 V96=W1
}
b
c2.					~motion
P1@"WAITING FOR STABLE WEIGHT"@
(V100=S&2)
iV100=2
{
 VV70=W1
 x95.
}
b
c3.					~print
P1@"WAITING FOR STABLE WEIGHT"@
V15=0
x6.
P4@"AXLE "V70.0.1"   "VV70.V90.8" lb\r\n"@
V15=1
x95.
b
c4.					~send axle off /green light
OXX01XXXX
x95.
b					
c5.					~RETURN TO ZERO
P1@"WAITING FOR AXLE "V70.0.1" EXIT"@		
iW1<V91		
{
 w2=V95
 x95.
}	
b
c6.					~Weight increase or time out
(V100=V70+1)
P1@"WAITING FOR AXLE "V100.0.1" OR TOTAL"@
iV95=0
{
 CV87
 [
  c256.
  b
  c12.
  x95.
  b
 ]
}
e
{
 iw2=0
 {
  x95.
 }
}
iW1>V93
{
 (V70++)
 V94=0
}
b
c7.		
V15=0
x6.			~Total
P4@"TOTAL WEIGHT"@
V100=0
D50.
(V100=VV70+V100)
iV70=1
{
 P4@V100.V90.10" lb\r\n\"@
}
e
{
 (V70=V70-1)
 G50.
}
V70=1
V94=0
V15=1
b
]
G11.
E
~BEGIN SUBROUTINES
D40.
x99.
P1@"ENTRY DECIMAL"@V90=k0.1 			~get THE ENTRY DP LOC
x97.
P1@"ENTER ZERO TOLERANCE"@V91=kV90.8  		~print rearm zero tolerance
x97.		
P1@"TIME OUT(1=.1 SEC.)(0=DISABLE)"@V95=k0.3 	~TIME OUT FOR TOTAL
x97.
P1@"MINIMUM AXLE WT."@V93=kV90.8		~MIN. AXLE WT.
x97.
P1@"WEIGHT INCREASE MIN."@V88=kV90.8            ~MIN WT INCREASE
x97.
P1@"WT INCREASE TIME (1=0.1 SEC.)"@V89=kV90.3   ~MIN INCREASE TIME
x98.
E
D60.
V100=0
x99.
P1@"CLEAR AXLES? (1=YES)"@V100=k.0.1
iV100=1
{
 V70=1
 V94=0
}
x98.
E
D95.
(V94++)
E
D96.
 x99.
 V100=0
 P1@"ENTER PASSWORD(PRESS ENTER)"@
 V99=0
 V99=k0.5
 x98.
 iV99=2001
 {
  V100=1			      		~password good
 }
E
D97.
P1@" "@
E
D98.
P1@" "@					~blank all text
P0@"\0"@P1@" "@				~release big display 
E
D99.
P0@" "@					~blank big display
P1@" "@					~blank disp 1
E	
E